home *** CD-ROM | disk | FTP | other *** search
/ MacWorld 1999 March - Disc 1 / Macworld (1999-03) (Disk 1).dmg / Shareware World / Utilities / Text Processing / Alpha / Tcl / Modes / latex Mode / latexEnvironments.tcl < prev    next >
Encoding:
Text File  |  1998-11-14  |  19.9 KB  |  736 lines  |  [TEXT/ALFA]
  1. ## -*-Tcl-*-
  2.  # ###################################################################
  3.  #  Vince's  Additions - an extension package for Alpha
  4.  # 
  5.  #  FILE: "latexEnvironments.tcl"
  6.  #                                    created: 22/1/98 {9:00:25 am} 
  7.  #                                last update: 14/11/98 {9:10:31 am} 
  8.  #  Author: Vince Darley
  9.  #  E-mail: <darley@fas.harvard.edu>
  10.  #    mail: Division of Engineering and Applied Sciences, Harvard University
  11.  #          Oxford Street, Cambridge MA 02138, USA
  12.  #     www: <http://www.fas.harvard.edu/~darley/>
  13.  #  
  14.  # Some copyright (c) 1998  Vince Darley
  15.  # 
  16.  # See the file "license.terms" for information on usage and redistribution
  17.  # of this file, and for a DISCLAIMER OF ALL WARRANTIES.
  18.  # 
  19.  # Many procs written/adapted from Pierre Basso's.  Many thanks for
  20.  # the great improvements.
  21.  # ###################################################################
  22.  ##
  23.  
  24. #This item is off by default now.  Add it to your TeXPrefs.tcl if desired.
  25. #set TeXbodyOptions(enumerate) "\[•a|i•\]"
  26. set TeXbodyOptions(list) "\{••\}\{••\}"
  27. set TeXbodyOptions(figure) "\[tbp\]"
  28. set TeXbodyOptions(floatingfigure) "\{•width•\}"
  29.  
  30. # ◊◊◊◊ Embeddable environments ◊◊◊◊ #
  31.  
  32. proc TeX::Figure {} {
  33.     set fig_types [list "Normal" "Floating" \
  34.         "2 side-by-side" "3 side-by-side" "4 side-by-side" \
  35.         "2, one above the other" \
  36.         "4 in a 2x2 block" \
  37.         "6 with 3 across, 2 down" \
  38.         "6 with 2 across, 3 down" \
  39.         "other…" \
  40.         ]
  41.     set fig [listpick -p "Pick a figure type to insert:" $fig_types]
  42.     if {$fig == ""} { return "" }
  43.  
  44.     global TeXbodyOptions
  45.     if {$fig == "Floating"} {
  46.         set t $TeXbodyOptions(floatingfigure)
  47.     } else {
  48.         set t $TeXbodyOptions(figure)
  49.     }
  50.     append t "\n\t"
  51.  
  52.     switch $fig {
  53.         "Normal" -
  54.         "Floating" {
  55.             append t "\\centerline\{\\includegraphics\[•shape,orientation•\]"
  56.             append t "\{•graphics file•\}\}\r\t"
  57.             append t "\\caption•\[short title for t.o.f.\]•\{•caption•\}\r\t"
  58.             append t "\\protect[TeX::label fig]"
  59.             if {$fig == "Floating"} {
  60.                 text::replace {\begin{figure}} {\begin{floatingfigure}} 0
  61.                 text::replace {\end{figure}} {\end{floatingfigure}} 1
  62.                 TeX::RequirePackage floatflt
  63.             }
  64.         }
  65.         "2 side-by-side" {
  66.             append t [TeX::_subFigure 2 1]
  67.         }
  68.         "3 side-by-side" {
  69.             append t [TeX::_subFigure 3 1]
  70.         }
  71.         "4 side-by-side" {
  72.             append t [TeX::_subFigure 4 1]
  73.         }
  74.         "2, one above the other" {
  75.             append t [TeX::_subFigure 1 2]
  76.         }
  77.         "4 in a 2x2 block" {
  78.             append t [TeX::_subFigure 2 2]
  79.         }
  80.         "6 with 3 across, 2 down" {
  81.             append t [TeX::_subFigure 3 2]
  82.         }
  83.         "6 with 2 across, 3 down" {
  84.             append t [TeX::_subFigure 2 3]
  85.         }
  86.         "other…" {
  87.             set w [prompt "Number of subfigures, horizontally" "2"]
  88.             set h [prompt "Number of subfigures, vertically" "2"]
  89.             append t [TeX::_subFigure $w $h]
  90.         }
  91.         
  92.     }
  93.     return $t    
  94. }
  95.  
  96.  
  97. # This procedure is an improved version of tcl programming 
  98. # of tabular environment. 
  99. #
  100. # This TeX::tabular procedure asks for vertical and for horizontal
  101. # lines. But the main Improvements  affect   providing 
  102. # the list of options. When clicking in TeX menu mode 
  103. # the environment "tabular" this procedure asks for a list
  104. # of options given in following way:
  105. #  opt1 opt2 opt3 .....
  106. # opt1, 2, 3, .. are any kind of option allowed by LaTeX
  107. # for environment tabular:
  108. #     c l r c p m b 
  109. # Options >, <, @ and ! are also allowed and you can provide:
  110. #     >c >l >r >p >m >b
  111. #     c< l< r< p< m< b<
  112. #     c@ l@ r@ p@ m@ b@
  113. #     c! l! r! p! m! b!
  114. # Procedure tabular will put left and right braces in case of
  115. # options p, m, b, @, !.
  116. #
  117. # WARNING: space is needed between two options!!!!!!l 
  118. # 
  119. # If the number of options exceed the number of columns
  120. # a message is displayed and the list of options is again asked.
  121. # If the number of options is lesser thanthe number of columns
  122. # the missing options are provided as the last option of the list;
  123. # for example: 5 columns asked and a list of options  "c l r"  with
  124. # vertical line "yes" would create a tabular environment:
  125. # \begin{tabular}{|c|l|r|r|r|}
  126. #
  127. # Pierre BASSO 
  128. # email:basso@lim.univ-mrs.fr
  129. #
  130.  
  131. proc TeX::BuildTabular {env} {
  132.  
  133. # ask for number of rows, columns, vertical and horizontal lines and options
  134.     set values [dialog -w 500 -h 400\
  135.       -t "how many rows? " 10 10 180 30 -e "3" 220 10 240 30 \
  136.       -t "how many columns? " 10 40 180 60 -e "3" 220 40 240 60 \
  137.       -t "vertical line (yes/no)? " 10 80 200 100 -e "yes" 220 80 250 100 \
  138.       -t "horizontal line (yes/no)? " 10 110 200 130 -e "yes" 220 110 250 130 \
  139.       -t "options:  c l r p m b  >c >l >r >p >m >b  c< l< r< p< m< b<" 10 150 400 170\
  140.       -t " c@ l@ r@ p@ m@ b@  c! l! r! p! m! b!" 140 170 400 190\
  141.       -e "c" 220 200 450 230 \
  142.       -t "position  (b/t or empty)" 10 250 180 270 -e "" 220 250 240 270\
  143.       -t "width if tabular*" 10 290 180 310 -e "" 220 290 320 310\
  144.       -b OK 50 350 115 370 -b Cancel 250 350 315 370]
  145.     set cancel [string trim [lindex $values 8]]
  146.     if {$cancel == 1} {beep ; return}
  147.  
  148. #   search for number of rows, default 3
  149. #   search for number of columns, default 3    
  150. #   
  151.     set numberRows [string trim [lindex $values 0]]
  152.     set numberColumns [string trim [lindex $values 1]]                        
  153.     if {![is::PositiveInteger $numberRows] || ![is::PositiveInteger $numberColumns]} {
  154.         beep
  155.         alertnote "invalid input:  unsigned, positive integer required"
  156.         return
  157.     }
  158.  
  159. # ask for  vertical lines : default yes
  160.     set vline [string trim [lindex $values 2]]
  161.     if {$vline == "yes" } {set vline "|" } else { set vline "" }
  162.  
  163. # tabular options 
  164.     set options [string trim [lindex $values 4]]
  165.     set numberOpts [llength $options]
  166.     set arg "{$vline"
  167.     for {set j 0} {$j < $numberColumns} {incr j} {
  168.         if {$j < $numberOpts} {
  169.             set optCol [lindex $options $j]
  170.         }
  171.         if {$optCol == "c" || $optCol == "l" || $optCol == "r"} {
  172.            append arg "$optCol$vline"
  173.            continue
  174.         }
  175.         if {$optCol == "p" || $optCol == "m" || $optCol == "b"\
  176.             || $optCol == "@" || $optCol == "!"} {
  177.             append arg "$optCol\{••\}$vline"
  178.             continue
  179.         }
  180.         if {$optCol == ">c" || $optCol == ">l" || $optCol == ">r"} {
  181.             append arg  ">\{••\}"    
  182.             set secondopt [string index $optCol 1]
  183.             append arg "$secondopt$vline"
  184.             continue
  185.         }
  186.         if {$optCol == ">p" || $optCol == ">m" || $optCol == ">b"} {
  187.             append arg  ">\{••\}"    
  188.             set secondopt [string index $optCol 1]
  189.             append arg "$secondopt\{••\}$vline"
  190.             continue
  191.         }
  192.         if {$optCol == "c<" || $optCol == "l<" || $optCol == "r<"} {
  193.             set secondopt [string index $optCol 0]
  194.             append arg "$secondopt<\{••\}$vline"
  195.             continue
  196.         }
  197.         if {$optCol == "p<" || $optCol == "m<" || $optCol == "b<"} {
  198.             set secondopt [string index $optCol 0]
  199.             append arg "$secondopt\{••\}<\{••\}$vline"
  200.             continue
  201.         }
  202.         if {$optCol == "c@" || $optCol == "l@" || $optCol == "r@"} {
  203.             set secondopt [string index $optCol 0]
  204.             append arg "$secondopt@\{••\}"
  205.             continue
  206.         }
  207.         if {$optCol == "p@" || $optCol == "m@" || $optCol == "b@"} {
  208.             set secondopt [string index $optCol 0]
  209.             append arg "$secondopt\{••\}@\{••\}"
  210.             continue
  211.         }
  212.         if {$optCol == "c!" || $optCol == "l!" || $optCol == "r!"} {
  213.             set secondopt [string index $optCol 0]
  214.             append arg "$secondopt!\{••\}"
  215.             continue
  216.         }
  217.         if {$optCol == "p!" || $optCol == "m!" || $optCol == "b!"} {
  218.             set secondopt [string index $optCol 0]
  219.             append arg "$secondopt\{••\}!\{••\}"
  220.             continue
  221.         }
  222.     }
  223.     append arg "}"
  224.     append t $arg "\r\t"
  225. # set horizontal lines 
  226.     set hline [string trim [lindex $values 3]]
  227.     if {$hline == "yes"} {set hline "\\hline" } else {set hline "" }
  228.     set body "$hline\r\t"
  229.     for {set i 1} {$i <= $numberRows} {incr i} {
  230.         append body "[buildRow $numberColumns]"
  231.         append body "  \\\\\r\t$hline\r\t"
  232.     }
  233.     append t $body "•• "
  234. # set width if tabular*
  235.     if {$env == "tabular*"} {
  236.         set width [string trim [lindex $values 6]]
  237.         if {$width == ""} {set width "••"}
  238.         append t "\{" $width "\}" 
  239.     }    
  240.       
  241. # set position
  242.     set position [string trim [lindex $values 5]]
  243.     if {$position != ""} {
  244.         append t "\[" $position "\]" 
  245.     }
  246.     return $t
  247. }
  248.  
  249. #####################  lists  ##########################
  250.  
  251. #
  252. # Build lists. 
  253. # This procedure is called for building environments itemize, enumerate,
  254. # description, list and trivlist.
  255. #
  256. # Pierre BASSO 
  257. # email:basso@lim.univ-mrs.fr
  258.  
  259. proc TeX::BuildList {env} {
  260.     prompt::simple \
  261.       [list "how many items?" numberitems 3 N] 
  262.     global TeXbodyOptions
  263.     if [info exists TeXbodyOptions($env)] {
  264.         set t $TeXbodyOptions($env)
  265.     }
  266.     append t "\n\t"
  267.     
  268.     for {set j 1} {$j <= $numberitems} {incr j} {
  269.         if {$env == "description" || $env == "trivlist"} {
  270.             append t "\\item\[••\] ••"
  271.         } else {
  272.             append t "\\item ••"
  273.         }
  274.         if {$j < $numberitems} {append t "\r\r\t"}
  275.     }
  276.     return $t
  277. }
  278.  
  279. # ◊◊◊◊ Boxes ◊◊◊◊ #
  280.  
  281. proc TeX::parbox {} {
  282.     prompt::simple \
  283.       [list "position (optional)?" position ""] \
  284.       [list "height (optional)?" height ""] \
  285.       [list "inner position (optional)?" innerpos ""] \
  286.       [list "width?" width 3in]
  287.  
  288.     if {$position != ""} {
  289.         append res "\[$position\]"
  290.     }
  291.     if {$height != ""} {
  292.         append res "\[$height\]"
  293.     }
  294.     if {$innerpos != ""} {
  295.         append res "\[$innerpos\]"
  296.     }
  297.     if {$width == ""} { set width "•required width•" }
  298.     append res "\{$width\}\{••\}"
  299.     return $res    
  300. }  
  301.  
  302. proc TeX::boxes {} {
  303.     prompt::simple \
  304.       [list "width (optional)?" width ""] \
  305.       [list "position (optional)?" position ""]
  306.     
  307.     if {$width != ""} {
  308.         append res "\[$width\]"
  309.     } 
  310.     if {$position != ""} {
  311.         append res "\[$position\]"
  312.     }
  313.     append res "\{••\}"
  314.     return $res        
  315. }
  316.  
  317. proc TeX::raisebox {} {
  318.     prompt::simple \
  319.       [list "lift?" lift ""] \
  320.       [list "depth (optional)?" depth ""] \
  321.       [list "height (optional)?" height ""]
  322.     
  323.     if {$lift == ""} {set lift "•required lift•"}
  324.     append res "\{$lift\}"
  325.     if {$depth != ""} {
  326.         append res "\[$depth\]"
  327.     }
  328.     if {$height != ""} {
  329.         append res "\[$height\]"
  330.     }
  331.     
  332.     append res "\{••\}"
  333.     return $res    
  334.     
  335. }
  336.  
  337. proc TeX::sbox {} {
  338.     prompt::simple \
  339.       [list "command?" command ""] 
  340.     if {$command == ""} {set command "•required command•"}
  341.     append res "\{$command\}\{••\}"
  342.     return $res    
  343. }    
  344.  
  345. proc TeX::savebox {} {
  346.     prompt::simple \
  347.       [list "command?" command ""] \
  348.       [list "width (optional)?" width ""] \
  349.       [list "position (optional)?" position ""] 
  350.     
  351.     if {$command == ""} {set command "•required command•"}
  352.     append res "\{$command\}"
  353.     
  354.     if {$width != ""} {
  355.         append res "\[$width\]"
  356.     }
  357.     if {$position != ""} {
  358.         append res "\[$position\]"
  359.     }
  360.     
  361.     append res "\{•body•\}"
  362.     return $res    
  363.     
  364. }
  365.  
  366. proc TeX::rule {} {
  367.     prompt::simple \
  368.       [list "lift (optional)?" position ""] \
  369.       [list "width?" width ""] \
  370.       [list "height?" height ""]
  371.     if {$lift != ""} {
  372.         append res "\[$lift\]"
  373.     } 
  374.     
  375.     if {$width == ""} {set width "•required width•"}
  376.     append res "\{$width\}"
  377.     
  378.     if {$height == ""} { set height "•required height•" }
  379.     append res "\{$height\}•rule body•"
  380.  
  381.     return $res
  382. }
  383.  
  384. proc TeX::minipage {} {
  385.     prompt::simple \
  386.       [list "position (optional)?" position ""] \
  387.       [list "height (optional)?" height ""] \
  388.       [list "inner position (optional)?" innerpos ""] \
  389.       [list "width?" width 3in]
  390.     if {$position != ""} {
  391.         append res "\[$position\]"
  392.     }
  393.     if {$height != ""} {
  394.         append res "\[$height\]"
  395.     }
  396.     if {$innerpos != ""} {
  397.         append res "\[$innerpos\]"
  398.     }
  399.     if {$width == ""} { set width "•required width•" }
  400.     append res "\{$width\}\r\t•minipage body•"
  401.     return $res
  402. }
  403.  
  404. # ◊◊◊◊ Maths ◊◊◊◊ #
  405.  
  406. #    
  407. # Pierre BASSO 
  408. # email:basso@lim.univ-mrs.fr
  409. #
  410.  
  411. #
  412. # All the types of matrix
  413. # 
  414. #
  415. proc TeX::matrix {} {
  416.     prompt::simple \
  417.       [list "how many rows?" numberRows 2 N] \
  418.       [list "how many columns?" numberColumns 2 N]
  419.     set body "\r"
  420.     # build matrix
  421.     for {set i 1} {$i <= $numberRows} {incr i} {
  422.         append body "\t[buildRow $numberColumns]  "
  423.         if {$i != $numberRows} { append body "\\\\\r" }
  424.     }
  425.  
  426.     return $body
  427. }
  428.  
  429. #
  430. # Alignment at a single place of mathematical formula
  431. #
  432. proc TeX::align {} {
  433.     prompt::simple \
  434.       [list "how many equations?" numberRows 2 N] 
  435.     
  436.     #  align is a tabular with two columns
  437.     set numberColumns 2                            
  438.     # build alignment
  439.     set res "\r"
  440.     for {set i 1} {$i <= $numberRows} {incr i} {
  441.         append res "\t•• & •• [TeX::label eq]"
  442.         if {$i != $numberRows} { append res "\\\\\r" }
  443.     }
  444.     return $res    
  445. }
  446.  
  447.  
  448. #
  449. # Alignment at several places of mathematical formula
  450. #
  451. proc TeX::alignat {} {
  452.     prompt::simple \
  453.       [list "how many equations?" numberRows 2 N] \
  454.       [list "how many alignments?" numberColumns 2 N]
  455.  
  456.     append res "\{$numberColumns\}\r"
  457.     set numberColumns [expr $numberColumns*2 - 1]
  458.     # build alignment
  459.     for {set i 1} {$i <= $numberRows} {incr i} {
  460.         set j 1
  461.         while {$j < $numberColumns} {
  462.             append res "\t•• & "
  463.             incr j
  464.         }
  465.         append res "••  [TeX::label eq]"
  466.         if {$i != $numberRows} { append res "\\\\\r" }
  467.     }
  468.     return $res
  469. }
  470.  
  471.  
  472. # ◊◊◊◊ embeddable proc helpers ◊◊◊◊ #
  473.  
  474. ## 
  475.  # -------------------------------------------------------------------------
  476.  # 
  477.  # "TeX::_subFigure" --
  478.  # 
  479.  #  This is a helper, it is only called form the above TeX::Figure proc.
  480.  # -------------------------------------------------------------------------
  481.  ##
  482. proc TeX::_subFigure {w h} {
  483.     TeX::RequirePackage subfigure
  484.     set t "\\centering\r\t"
  485.     set wnum [lindex {x "" two three four five six seven} $w]
  486.     for {set hh $h} {$hh >0} {incr hh -1} {
  487.         for {set ww $w} {$ww >0} {incr ww -1} {
  488.             append t "\\subfigure\[•subfig caption•\]\{[TeX::label fig]%\r\t"
  489.             append t "\t\\includegraphics\[width=\\figs${wnum}\]"
  490.             append t "\{•graphics file•\}\}"
  491.             if {$ww != 1} {
  492.                 append t "\\goodgap${wnum}\r\t"
  493.             } else {
  494.                 if {$hh != 1} {
  495.                     append t "\\\\\r\t"
  496.                 } else {
  497.                     append t "%\r\t"
  498.                 }
  499.             }
  500.         }
  501.     }
  502.     append t "\\caption•\[short caption for t.o.f.\]•\{•caption•\}\r\t"
  503.     append t "[TeX::label fig]"
  504. }
  505.  
  506. #--------------------------------------------------------------------------
  507. # ◊◊◊◊ Environments: ◊◊◊◊
  508. #--------------------------------------------------------------------------
  509.  
  510. proc enumerate {} {
  511.     set envName "enumerate"
  512.     prompt::var "$envName:  how many items?" numberItems 3 \
  513.       is::PositiveInteger 1 "invalid input:  unsigned, postive integer required"
  514.     if {$numberItems} {
  515.         set body "\t\\item  •type first item•"
  516.         for {set i 1} {$i < $numberItems} {incr i} {
  517.             append body "\r\r\t\\item  ••"
  518.         }
  519.         append body "\r"
  520.     } else {
  521.         set body "\t••\r"
  522.     }
  523.     insertEnvironment $envName "" $body
  524. }
  525. proc itemize {} {
  526.     set envName "itemize"
  527.     prompt::var "$envName:  how many items?" numberItems 3 \
  528.       is::PositiveInteger 1 "invalid input:  unsigned, postive integer required"
  529.     if {$numberItems} {
  530.         set body "\t\\item  •type first item•"
  531.         for {set i 1} {$i < $numberItems} {incr i} {
  532.             append body "\r\r\t\\item  ••"
  533.         }
  534.         append body "\r"
  535.     } else {
  536.         set body "\t••\r"
  537.     }
  538.     insertEnvironment $envName "" $body
  539. }
  540. proc description {} {
  541.     set envName "description"
  542.     prompt::var "$envName:  how many items?" numberItems 3 \
  543.       is::PositiveInteger 1 "invalid input:  unsigned, postive integer required"
  544.     if {$numberItems} {
  545.         set body "\t\\item\[•label•\]  ••"
  546.         for {set i 1} {$i < $numberItems} {incr i} {
  547.             append body "\r\r\t\\item\[••\]  ••"
  548.         }
  549.         append body "\r"
  550.     } else {
  551.         set body "\t••\r"
  552.     }
  553.     insertEnvironment $envName "" $body
  554. }
  555. proc thebibliography {} {
  556.     set envName "thebibliography"
  557.     prompt::var "$envName:  how many items?" numberItems 3 \
  558.       is::PositiveInteger 1 "invalid input:  unsigned, postive integer required"
  559.     set arg "{9•length of the key field•}"
  560.     if {$numberItems} {
  561.         if {$numberItems > 9} {set arg "{99•length of the key field•}"}
  562.         set body "\t\\bibitem{••}  ••"
  563.         for {set i 1} {$i < $numberItems} {incr i} {
  564.             append body "\r\r\t\\bibitem{••}  ••"
  565.         }
  566.         append body "\r"
  567.     } else {
  568.         set body "\t••\r"
  569.     }
  570.     insertEnvironment $envName $arg $body
  571. }
  572. proc slide {} { doWrapEnvironment "slide" }
  573. proc overlay {} { doWrapEnvironment "overlay" }
  574. proc note {} { doWrapEnvironment "note" }
  575. proc figure {} {
  576.     global TeXmodeVars
  577.     set envName "figure"
  578.     set envArg "tbp"
  579.     set arg "\[${envArg}•Modify this argument?  (t=top; b=bottom; p=page; h=here; !=try harder)•\]"
  580.     set theIndentation [text::indentString [getPos]]
  581.     append arg "\r$theIndentation\t\\centering"
  582.     set body ""
  583.     set macro [lindex $TeXmodeVars(boxMacroNames) 0]
  584.     if { $macro != "" } {
  585.         set restOfMacros [cdr $TeXmodeVars(boxMacroNames)]
  586.         if { ![llength $restOfMacros] } {
  587.             append body "\t\\$macro{••}\r"
  588.         } else {
  589.             set cmd [list prompt "Choose a box macro:"]
  590.             lappend cmd $macro "" 
  591.             foreach boxMacroName $TeXmodeVars(boxMacroNames) {
  592.                 lappend cmd $boxMacroName
  593.             }
  594.             catch $cmd macro
  595.             if {$macro == "cancel"} {
  596.                 message "operation canceled"
  597.                 return
  598.             } elseif {$macro == ""} {
  599.                 # do nothing
  600.             } else {
  601.                 append body "\t\\$macro{••}\r"
  602.             }
  603.         }
  604.     }
  605.     append body "\t\\caption{••}\r"
  606.     append body "\t[TeX::label fig]\r"
  607.     if { $macro == "" } {
  608.         wrapEnvironment $envName $arg $body
  609.     } else {
  610.         insertEnvironment $envName $arg $body
  611.     }
  612. }
  613. proc table {} {
  614.     set envName "table"
  615.     set envArg "tbp"
  616.     set arg "\[${envArg}•Modify this argument?  (t=top; b=bottom; p=page; h=here; !=try harder)•\]"
  617.     set theIndentation [text::indentString [getPos]]
  618.     append arg "\r$theIndentation\t\\centering"
  619.     # The following statement puts the caption at the top:
  620.     append arg "\r$theIndentation\t\\caption{••}"
  621.     # The following statement puts the caption at the bottom:
  622. #     set body "\t\\caption{••}\r"
  623.     append body "\t[TeX::label tbl]\r"
  624.     wrapEnvironment $envName $arg $body
  625. }
  626. proc buildRow {jmax} {
  627.     set txt "••"
  628.     for {set j 1} {$j < $jmax} {incr j} {
  629.         append txt " & ••"
  630.     }
  631.     return $txt
  632. }
  633. proc tabular {} {
  634.     set envName "tabular"
  635.     prompt::var "$envName:  how many rows?" numberRows 3 \
  636.       is::PositiveInteger 1 "invalid input:  unsigned, postive integer required"
  637.     prompt::var "$envName:  how many columns?" numberColumns 3 \
  638.       is::PositiveInteger 1 "invalid input:  unsigned, postive integer required"
  639.     set arg "{|"
  640.     for {set j 1} {$j <= $numberColumns} {incr j} {
  641.         append arg "c•modify this argument?•|"
  642.     }
  643.     append arg "}"
  644.     set body "\t\\hline\r"
  645.     for {set i 1} {$i <= $numberRows} {incr i} {
  646.         append body "\t[buildRow $numberColumns]"
  647.         append body "  \\\\\r\t\\hline\r"
  648.     }
  649.     insertEnvironment $envName $arg $body
  650. }
  651. proc verbatim {} { doWrapEnvironment "verbatim" }
  652. proc quote {} { doWrapEnvironment "quote" }
  653. proc quotation {} { doWrapEnvironment "quotation" }
  654. proc verse {} { doWrapEnvironment "verse" }
  655. proc flushleft {} { doWrapEnvironment "flushleft" }
  656. proc center {} { doWrapEnvironment "center" }
  657. proc flushright {} { doWrapEnvironment "flushright" }
  658. proc minipage {} {
  659.     set arg "\[••\]{••}"
  660.     wrapEnvironment "minipage" $arg ""
  661.     message "enter the position \[b|c|t\] of the minipage, then the width"
  662. }
  663.  
  664. #--------------------------------------------------------------------------
  665. # ◊◊◊◊ Math Environments: ◊◊◊◊
  666. #--------------------------------------------------------------------------
  667.  
  668. proc math {} { checkMathMode "math" 0; doWrapEnvironment "math" }
  669. proc displaymath {} {
  670.     checkMathMode "displaymath" 0
  671.     global TeXmodeVars
  672.     if { $TeXmodeVars(useBrackets) } {
  673.         doWrapStructure {\[} {} {\]}
  674.     } else {
  675.         doWrapEnvironment "displaymath"
  676.     }
  677. }
  678.  
  679. proc mathEnvironment {envName} {
  680.     checkMathMode $envName 0
  681.     set body "\t[TeX::label eq]\r"
  682.     if {[wrapEnvironment $envName "" $body]} {
  683.         set msgText "equation wrapped"
  684.     } else {
  685.         set msgText "enter equation"
  686.     }
  687.     message $msgText
  688. }
  689.  
  690. proc TeXmathenv {envName} {
  691.     checkMathMode "$envName" 0
  692.     
  693.     prompt::var "$envName:  how many rows?" numberRows 3 \
  694.       is::PositiveInteger 1 "invalid input:  unsigned, postive integer required"
  695.  
  696.     switch $envName {
  697.         "eqnarray*" {
  698.             set row "\t[buildRow 3]"
  699.             for {set i 1} {$i < $numberRows} {incr i} {
  700.                 append body $row
  701.                 append body "  \\\\\r"
  702.             }
  703.             append body $row
  704.             append body "\r"
  705.         }
  706.         "eqnarray" {
  707.             set row "\t[buildRow 3]\r\t[TeX::label eq]"
  708.             for {set i 1} {$i < $numberRows} {incr i} {
  709.                 append body $row
  710.                 append body "  \\\\\r"
  711.             }
  712.             append body $row
  713.             append body "\r"
  714.         }
  715.         "array" {
  716.             prompt::var "$envName:  how many columns?" numberColumns 3 \
  717.               is::PositiveInteger 1 "invalid input:  unsigned, postive integer required"
  718.             set arg "{"
  719.             for {set j 1} {$j <= $numberColumns} {incr j} {
  720.                 append arg "c"
  721.             }
  722.             append arg "•Modify this argument?  (c=center; l=left; r=right; p{width}; a{text})•}"
  723.             set row "\t[buildRow $numberColumns]"
  724.             for {set i 1} {$i < $numberRows} {incr i} {
  725.                 append body $row
  726.                 append body "  \\\\\r"
  727.             }
  728.             append body $row
  729.             append body "\r"
  730.             insertEnvironment $envName $arg $body
  731.             return
  732.         }
  733.     }
  734.     insertEnvironment $envName "" $body
  735. }
  736.